pamac-classic/src/aur.vala

/*
 *  pamac-vala
 *
 *  Copyright (C) 2014-2016 Guillaume Benoit <guillaume@manjaro.org>
 *
 *  This program is free software; you can redistribute it and/or modify
 *  it under the terms of the GNU General Public License as published by
 *  the Free Software Foundation; either version 3 of the License, or
 *  (at your option) any later version.
 *
 *  This program is distributed in the hope that it will be useful,
 *  but WITHOUT ANY WARRANTY; without even the implied warranty of
 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 *  GNU General Public License for more details.
 *
 *  You should have received a get of the GNU General Public License
 *  along with this program.  If not, see <http://www.gnu.org/licenses/>.
 */

namespace AUR {
	// AUR urls
	const string aur_url = "http://aur.archlinux.org";
	const string rpc_url = aur_url + "/rpc/?v=5";
	const string rpc_search = "&type=search&arg=";
	const string rpc_multiinfo = "&type=info";
	const string rpc_multiinfo_arg = "&arg[]=";

	public Json.Array search (string[] needles) {
		var prev_inter = new Json.Array ();
		string uri = rpc_url + rpc_search + Uri.escape_string (needles[0]);
		var session = new Soup.Session ();
		var message = new Soup.Message ("GET", uri);
		var parser = new Json.Parser ();
		session.send_message (message);
		try {
			parser.load_from_data ((string) message.response_body.flatten ().data, -1);
		} catch (Error e) {
			print (e.message);
		}
		unowned Json.Node? root = parser.get_root ();
		if (root != null) {
			if (root.get_object ().get_string_member ("type") == "error") {
				stderr.printf ("Failed to search %s from AUR\n", needles[0]);
			} else {
				prev_inter = root.get_object ().get_array_member ("results");
			}
		}
		int needles_length = needles.length;
		if (needles_length == 1) {
			return prev_inter;
		}
		int i = 1;
		var inter = new Json.Array ();
		var found = new Json.Array ();
		while (i < needles_length) {
			inter = new Json.Array ();
			uri = rpc_url + rpc_search + Uri.escape_string (needles[i]);
			message = new Soup.Message ("GET", uri);
			session.send_message (message);
			try {
				parser.load_from_data ((string) message.response_body.flatten ().data, -1);
			} catch (Error e) {
				print (e.message);
			}
			root = parser.get_root ();
			if (root != null) {
				if (root.get_object ().get_string_member ("type") == "error") {
					stderr.printf ("Failed to search %s from AUR\n", needles[i]);
				} else {
					found = root.get_object ().get_array_member ("results");
					uint j = 0;
					uint k;
					uint found_length = found.get_length ();
					while (j < found_length) {
						unowned Json.Node found_node = found.get_element (j);
						k = 0;
						uint prev_inter_length = prev_inter.get_length ();
						while (k < prev_inter_length) {
							unowned Json.Node prev_inter_node = prev_inter.get_element (k);
							if (strcmp (found_node.get_object ().get_string_member ("Name"),
										prev_inter_node.get_object ().get_string_member ("Name")) == 0) {
								inter.add_element (prev_inter_node);
								prev_inter.remove_element (k);
								break;
							}
							k++;
						}
						j++;
					}
				}
			}
			if (i != (needles_length -1)) {
				prev_inter = inter;
			}
			i++;
		}
		return inter;
	}

	public Json.Array multiinfo (string[] pkgnames) {
		Json.Array results = new Json.Array ();
		if (pkgnames.length == 0) {
			return results;
		}
		var builder = new StringBuilder ();
		builder.append (rpc_url);
		builder.append (rpc_multiinfo);
		foreach (string pkgname in pkgnames) {
			builder.append (rpc_multiinfo_arg);
			builder.append (Uri.escape_string (pkgname));
		}
		var session = new Soup.Session ();
		var message = new Soup.Message ("GET", builder.str);
		session.send_message (message);
		var parser = new Json.Parser ();
		try {
			parser.load_from_data ((string) message.response_body.flatten ().data, -1);
		} catch (Error e) {
			print (e.message);
		}
		unowned Json.Node? root = parser.get_root ();
		if (root != null) {
			if (root.get_object ().get_string_member ("type") == "error") {
				stderr.printf ("Failed to multiinfo %s from AUR\n", builder.str);
			} else {
				results = root.get_object ().get_array_member ("results");
			}
		}
		return results;
	}
}