namespace Sernatur {
	namespace DB {
		using Postgres;
		using Wrapper;

		public class Categoria : GLib.Object {
			public uint id_categoria { get; set; default = 0; }
			public string descripcion_categoria { get; set; default = ""; }

			public Categoria (uint id_categoria = 0, string descripcion_categoria = "") {
				this.id_categoria = id_categoria;
				this.descripcion_categoria = descripcion_categoria;
			}

			public static Categoria[]? get_all_categorias(Database conn) {
				var res = conn.exec ("
SELECT id_categoria, descripcion_categoria FROM categoria
				");
				if (res.get_status () != ExecStatus.TUPLES_OK) {
					#if DEBUG
						error (conn.get_error_message ());
					#else
						warning (conn.get_error_message ());
						return null;
					#endif
				}

				var wra = new ResultWrapper (res);
				Categoria[] categorias = {};
				int n = res.get_n_tuples ();
				for (int i = 0; i < n; i++) {
					try {
						var categoria = new Categoria (wra.get_int_n (i, "id_categoria"),
							wra.get_string_n (i, "descripcion_categoria")
						);
						categorias += categoria;
					}
					catch (Error e) {
						#if DEBUG
							error (e.message);
						#else
							warning (e.message);
						#endif
					}
				}
				return categorias;
			}
		}
	}
}