/*
 * Copyright 2018-2019 Chris Cromer
 *
 * Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following conditions are met:
 *
 * 1. Redistributions of source code must retain the above copyright notice, this list of conditions and the following disclaimer.
 *
 * 2. Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following disclaimer in the documentation and/or other materials provided with the distribution.
 *
 * 3. Neither the name of the copyright holder nor the names of its contributors may be used to endorse or promote products derived from this software without specific prior written permission.
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 */

namespace LibSernatur {
	namespace DB {
		using Postgres;
		using Wrapper;

		/**
		 * The Turista class based on the database table
		 */
		public class Turista : GLib.Object {
			/**
			 * The RUT of the tourist
			 */
			public string rut_turista { get; set; default = ""; }
			/**
			 * The tourist name
			 */
			public string nombre_turista { get; set; default = ""; }
			/**
			 * The birth date of the tourist
			 */
			public string fecha_nacimento { get; set; default = ""; }
			/**
			 * The emergency contact
			 */
			public ContactoEmergencia contacto_emergencia { get; set; default = null; }

			/**
			 * Initilize the Turista class
			 * @param rut_turista The RUT of the tourist
			 * @param nombre_turista The tourist name
			 * @param fecha_nacimento The birth date of the tourist
			 * @param contacto_emergencia The emergency contact
			 */
			public Turista (string rut_turista = "", string nombre_turista = "", string fecha_nacimento = "", ContactoEmergencia? contacto_emergencia = null) {
				this.rut_turista = rut_turista;
				this.nombre_turista = nombre_turista;
				this.fecha_nacimento = fecha_nacimento;
				this.contacto_emergencia = contacto_emergencia;
			}

			/**
			 * Get all tuples and fields from database
			 * @param conn The database connection to use
			 * @return Returns a list of Turista
			 */
			public static List<Turista> get_all_turistas (Database conn) {
				var res = conn.exec ("
SELECT T.rut_turista, T.nombre_turista, T.fecha_nacimento,
C.id_contacto, C.telefono_emergencia, C.nombre_emergencia
FROM turista T
JOIN contacto_emergencia C ON (T.id_contacto = C.id_contacto)
				");
				if (res.get_status () != ExecStatus.TUPLES_OK) {
					#if DEBUG
						error (conn.get_error_message ());
					#else
						warning (conn.get_error_message ());
						return new List<Turista> ();
					#endif
				}

				var wra = new ResultWrapper (res);
				List<Turista> list = new List<Turista> ();
				int n = res.get_n_tuples ();
				for (int i = 0; i < n; i++) {
					try {
						var turista = new Turista (wra.get_string_n (i, "rut_turista"),
							wra.get_string_n (i, "nombre_turista"),
							wra.get_string_n (i, "fecha_nacimento"),
							new ContactoEmergencia (wra.get_int_n (i, "id_contacto"),
								wra.get_int_n (i, "telefono_emergencia"),
								wra.get_string_n (i, "nombre_emergencia")
							)
						);
						list.append (turista);
					}
					catch (Error e) {
						#if DEBUG
							error (e.message);
						#else
							warning (e.message);
						#endif
					}
				}
				return list;
			}
		}
	}
}
