namespace LibSernatur {
	namespace DB {
		using Postgres;
		using Wrapper;

		public class Descuento : GLib.Object {
			public uint id_descuento { get; set; default = 0; }
			public string descripcion_descuento { get; set; default = ""; }
			public float porcentaje { get; set; default = 0; }

			public Descuento (uint id_descuento = 0, string descripcion_descuento = "", float porcentaje = 0) {
				this.id_descuento = id_descuento;
				this.descripcion_descuento = descripcion_descuento;
				this.porcentaje = porcentaje;
			}

			public static Descuento[]? get_all_descuentos(Database conn) {
				var res = conn.exec ("
SELECT id_descuento, descripcion_descuento, porcentaje FROM descuento
				");
				if (res.get_status () != ExecStatus.TUPLES_OK) {
					#if DEBUG
						error (conn.get_error_message ());
					#else
						warning (conn.get_error_message ());
						return null;
					#endif
				}

				var wra = new ResultWrapper (res);
				Descuento[] descuentos = {};
				int n = res.get_n_tuples ();
				for (int i = 0; i < n; i++) {
					try {
						var descuento = new Descuento (wra.get_int_n (i, "id_descuento"),
							wra.get_string_n (i, "descripcion_descuento"),
							wra.get_float_n (i, "porcentaje")
						);
						descuentos += descuento;
					}
					catch (Error e) {
						#if DEBUG
							error (e.message);
						#else
							warning (e.message);
						#endif
					}
				}
				return descuentos;
			}
		}
	}
}
