namespace LibSernatur {
	namespace DB {
		using Postgres;
		using Wrapper;

		public class Enfermedad : GLib.Object {
			public uint id_enfermedad { get; set; default = 0; }
			public string descripcion_enfermedad { get; set; default = ""; }

			public Enfermedad (uint id_enfermedad = 0, string descripcion_enfermedad = "") {
				this.id_enfermedad = id_enfermedad;
				this.descripcion_enfermedad = descripcion_enfermedad;
			}

			public static Enfermedad[]? get_all_enfermedades(Database conn) {
				var res = conn.exec ("
SELECT id_enfermedad, descripcion_enfermedad FROM enfermedad
				");
				if (res.get_status () != ExecStatus.TUPLES_OK) {
					#if DEBUG
						error (conn.get_error_message ());
					#else
						warning (conn.get_error_message ());
						return null;
					#endif
				}

				var wra = new ResultWrapper (res);
				Enfermedad[] enfermedades = {};
				int n = res.get_n_tuples ();
				for (int i = 0; i < n; i++) {
					try {
						var enfermedad = new Enfermedad (wra.get_int_n (i, "id_enfermedad"),
							wra.get_string_n (i, "descripcion_enfermedad")
						);
						enfermedades += enfermedad;
					}
					catch (Error e) {
						#if DEBUG
							error (e.message);
						#else
							warning (e.message);
						#endif
					}
				}
				return enfermedades;
			}
		}
	}
}
